BAIN MUSC 539
Composing with Computers

MUSC 539 | Csound Instruments for Study | MIDI Note | Overtone Series

Csound Instruments for Study

Arpeggio of the Harmonic Series by Jean Claude Risset

This beautiful Csound instrument, designed by Jean Claude Risset, produces an arpeggiation in the Harmonic Series. One can hear very clearly the individual harmonics of the waveform stored in the Csound f-table named f1-- partials 10, 9, 8, 7, 6, 5, and 1--come into phase. Risset's score file was altered to arpeggiate over a fundamental pitch of C2 - 65.41 Hz., rather than original 96 Hz. The comments in the arpeggio.sco file are the author's.

from The Amsterdam Catalog of Csound Computer Instruments, John-Philipp Gather, Ed.


.mov, 28K, 7.1 sec.

arpeggio.orc

;arpeggio.orc

sr          =           44100
kr          =           4410
ksmps       =           10
nchnls      =           1

            instr       1

; p4 = freq of fundamental (Hz)
; p5 = amp
; p6 = initial offset of freq - .03 Hz

; init values correspond to freq. 
; offsets for oscillators based on original p6

i1          =           p6
i2          =           2*p6
i3          =           3*p6
i4          =           4*p6

; A de-click envelope
ampenv  linen   p5,.01,p3,.02  

; Nine oscillators with the same amplitude env
; and waveform, but slightly different
; frequencies to create the beating effect

a1      oscili  ampenv,p4,1    ;              65.41 Hz.    
a2      oscili  ampenv,p4+i1,1 ; 65.41 +.03 = 65.44 Hz.    
a3      oscili  ampenv,p4+i2,1 ; 65.41 +.06 = 65.47 Hz.  
a4      oscili  ampenv,p4+i3,1 ; 65.41 +.09 = 65.50 Hz.  
a5      oscili  ampenv,p4+i4,1 ; 65.41 +.12 = 65.53 Hz.  
a6      oscili  ampenv,p4-i1,1 ; 65.41 -.03 = 65.38 Hz.  
a7      oscili  ampenv,p4-i2,1 ; 65.41 -.06 = 65.35 Hz.  
a8      oscili  ampenv,p4-i3,1 ; 65.41 -.09 = 65.32 Hz.  
a9      oscili  ampenv,p4-i4,1 ; 65.41 -.12 = 65.29 Hz.  

        out     a1+a2+a3+a4+a5+a6+a7+a8+a9
        endin

arpeggio.sco

; arpeggio.sco

;--Harmonic No.-- 1   2   3   4   5   6   7   8   9   10
f1 0 1024   10    1   0   0   0   .7  .7  .7  .7  .7  .7

;       start   dur     freq    amp     offset
i1      1       7.1     65.41   2500    .03
e
Updated: March 13, 2001